Tero Laakso | Flash | Flash Away3D-planeettaselain

AS3-koodi

Olen pakannut kaiken yllä olevan Flash-komponentin tarvitseman koodin yhdeksi Away3DSphere-nimiseen luokkaan, jonka lähdekoodin tallensin tiedostoksi Away3DSphere.as:

            
package {

	import away3d.cameras.HoverCamera3D;
	import away3d.containers.View3D;
	import away3d.containers.Scene3D;
	import away3d.lights.DirectionalLight3D;
	
	import away3d.primitives.Sphere;
	import away3d.materials.PhongBitmapMaterial;
	
	import flash.display.Sprite;
	
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.events.MouseEvent;
	import flash.events.ProgressEvent;
	import flash.events.IOErrorEvent;
	
	import flash.display.BitmapData;
	import flash.display.Bitmap;
	import flash.utils.ByteArray;
	import flash.ui.Keyboard;
	
	import flash.net.FileFilter;
	import flash.net.FileReference;
	import flash.net.URLRequest;
	import flash.net.navigateToURL;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.text.TextFormat;
	
	import fl.controls.Button;
	import com.adobe.images.PNGEncoder;
	import com.adobe.images.JPGEncoder;

	public class Away3DSphere extends Sprite {
		
		private var scene:Scene3D;
		private var view:View3D;
		private var camera:HoverCamera3D;
		
		private var sP:Sphere;
		private var image:BitmapData;
		
		private var move:Boolean = false;
		private var lastPanAngle:Number;
		private var lastTiltAngle:Number;
		private var lastMouseX:Number;
		private var lastMouseY:Number;
		
		// allowed file types
        private var fileTypes:FileFilter = new FileFilter("Image", "*.jpg;*.jpeg;*;*.gif;*.png;*");
		private var loadFileRef:FileReference = new FileReference();
		private var saveFileRef:FileReference = new FileReference();
		
		private var loader:Loader;
		
		private var earthDayBtn:Button;
		private var earthNightBtn:Button;
		private var mapBtn:Button;
		
		private var loadBtn:Button;
		private var savePNGBtn:Button;
		private var saveJPGBtn:Button;
		
		// encoder to create file to save
		private var jpg:JPGEncoder = new JPGEncoder(100);
	
		public function Away3DSphere()
		{
			scene             = new Scene3D();
			scene.updateLight = true;
			
			camera = new HoverCamera3D();
			camera.x            = 0;
			camera.y            = 0;
			camera.z            = -200;
			
			camera.mintiltangle = 15;
			camera.maxtiltangle = 65;
			
			view = new View3D({width:800, height:600, x:400, y:300, camera:camera, scene:scene});
			addChild(view);
			
			sP = new Sphere({radius: 150, segmentsH: 18, segmentsW: 26});
			sP.x         = 0;
			sP.y         = 0;
			sP.z         = 50;
			sP.alpha     = 1.0;
			sP.ownCanvas = true;
			sP.ownLights = true;
			
			image       = new earth_day(1000,500);
			sP.material = new PhongBitmapMaterial(image, {shininess:30,specular:0.8});
			
			scene.addChild(sP);
			
			stage.doubleClickEnabled = true;
			doubleClickEnabled = true;
			
			addEventListener(Event.ENTER_FRAME, enterFrameHandler);
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, MouseDown);
			stage.addEventListener(MouseEvent.MOUSE_UP, MouseUp);
			
			// add event listeners for upload
			loadFileRef.addEventListener(Event.SELECT, fileSelected);
			loadFileRef.addEventListener(Event.COMPLETE, loadCompleted);
			loadFileRef.addEventListener(IOErrorEvent.IO_ERROR, ioerror);
			
			var tF:TextFormat = new TextFormat();
			tF.color          = 0x000000;
			tF.font           = "Verdana";
			tF.size           = 10;
			
			earthDayBtn = new Button();
			earthDayBtn.setStyle("textFormat", tF);
			earthDayBtn.label = "Maa (päivä)";
			
			earthDayBtn.addEventListener(MouseEvent.CLICK, earthDayBtnHandler);
			stage.addChild(earthDayBtn);
			
			earthDayBtn.x = 25;
			earthDayBtn.y = 20;
			
			earthNightBtn = new Button();
			earthNightBtn.setStyle("textFormat", tF);
			earthNightBtn.label = "Maa (yö)";
			
			earthNightBtn.addEventListener(MouseEvent.CLICK, earthNightBtnHandler);
			stage.addChild(earthNightBtn);
			
			earthNightBtn.x = 155;
			earthNightBtn.y = 20;
			
			mapBtn = new Button();
			mapBtn.setStyle("textFormat", tF);
			mapBtn.label = "Karttoja";
			
			mapBtn.addEventListener(MouseEvent.CLICK, mapBtnHandler);
			stage.addChild(mapBtn);
			
			mapBtn.x = 285;
			mapBtn.y = 20;
			
			loadBtn = new Button();
			loadBtn.setStyle("textFormat", tF);
			loadBtn.label = "Lataa kuva";
			
			loadBtn.addEventListener(MouseEvent.CLICK, loadBtnHandler);
			stage.addChild(loadBtn);
			
			loadBtn.x = 415;
			loadBtn.y = 20;
			
			savePNGBtn = new Button();
			savePNGBtn.setStyle("textFormat", tF);
			savePNGBtn.label = "Tallenna PNG";
			
			savePNGBtn.addEventListener(MouseEvent.CLICK, savePNGBtnHandler);
			stage.addChild(savePNGBtn);
			
			savePNGBtn.x = 545;
			savePNGBtn.y = 20;
			
			saveJPGBtn = new Button();
			saveJPGBtn.setStyle("textFormat", tF);
			saveJPGBtn.label = "Tallenna JPG";
			
			saveJPGBtn.addEventListener(MouseEvent.CLICK, saveJPGBtnHandler);
			stage.addChild(saveJPGBtn);
			
			saveJPGBtn.x = 675;
			saveJPGBtn.y = 20;
		}
		
		function earthDayBtnHandler(e:MouseEvent):void
		{
			image       = new earth_day(1000,500);
			sP.material = new PhongBitmapMaterial(image, {shininess:30,specular:0.8});
		}
		
		function earthNightBtnHandler(e:MouseEvent):void
		{
			image       = new earth_night(1000,500);
			sP.material = new PhongBitmapMaterial(image, {shininess:30,specular:0.8});
		}
		
		function mapBtnHandler(e:MouseEvent):void
		{
			var linkURL:URLRequest = new URLRequest("http://planetpixelemporium.com/earth.html"); 
			navigateToURL(linkURL); 
		}
		
		function savePNGBtnHandler(e:MouseEvent):void
		{
			capturePNG();
		}
		
		// capture image and save back to client
		private function capturePNG():void{
			var bitmapData:BitmapData = new BitmapData(this.width, this.height);
			bitmapData.draw(this);
			var ba:ByteArray = PNGEncoder.encode(bitmapData);
			
			saveFileRef.save(ba,"image.png");
		}
		
		function saveJPGBtnHandler(e:MouseEvent):void
		{
			captureJPG();
		}
		
		// capture image and save back to client
		private function captureJPG():void{
			var bitmapData:BitmapData = new BitmapData(this.width, this.height);
			bitmapData.draw(this);
			var ba:ByteArray = jpg.encode(bitmapData);
			
			saveFileRef.save(ba,"image.jpg");
		}

		function loadBtnHandler(e:MouseEvent):void
		{
			loadFileRef.browse();
		}
		
		 // called after a file has been selected within the file system browser
		private function fileSelected(evt:Event):void {
			loadFileRef.load();
		}

		// load has completed
		private function loadCompleted(e:Event):void {
			loader = new Loader();

			loader.contentLoaderInfo.addEventListener(Event.COMPLETE,imageLoadComplete);
			loader.loadBytes(loadFileRef.data);
		}
		
		// This will execute when load completes
		private function imageLoadComplete(e:Event):void {
			var bt:Bitmap = loader.content as Bitmap;
			image = bt.bitmapData;
			sP.material = new PhongBitmapMaterial(image, {shininess:30,specular:0.8});
		}
		
		// load error
		public function ioerror(e:IOErrorEvent):void{
			//Alert.show(e.text,"Error");
		}

		function MouseDown(e:MouseEvent):void
		{
			lastPanAngle = camera.targetpanangle;
			lastTiltAngle = camera.targettiltangle;
			lastMouseX = stage.mouseX;
			lastMouseY = stage.mouseY;
			move = true;
		}
		 
		function MouseUp(e:MouseEvent):void
		{
			move = false;
		}
		 
		function enterFrameHandler(e:Event):void
		{
			// rerender viewport
			var cameraSpeed:Number = 0.3; // Approximately same speed as mouse movement.
			if (move) {
				camera.targetpanangle = cameraSpeed*(stage.mouseX - lastMouseX) + lastPanAngle;
				camera.targettiltangle = cameraSpeed*(stage.mouseY - lastMouseY) + lastTiltAngle;
			}
			
			camera.hover(); 
			view.render();
		}
		
		 // The KeyboardEvent.KEY_DOWN event handler manage key pressed by user
      private function keyPressed(event:KeyboardEvent):void
      {
         if(event.keyCode == Keyboard.UP) {
			if(event.shiftKey == false) { 
				sP.y +=10;
			}
			else {
				sP.rotationX += 5;
			}
			
			if(event.ctrlKey == true) { 	
				camera.distance -= 20;
			}
		 }
		 else if(event.keyCode == Keyboard.DOWN) {
			if(event.shiftKey == false) { 
				sP.y -=10;
			}
			else {
				sP.rotationX -= 5;
			}
			
			if(event.ctrlKey == true) { 	
				camera.distance += 20;
			}
		 }
		 else if(event.keyCode == Keyboard.RIGHT) {
			if(event.shiftKey == false) { 	
				sP.x +=10;
		 	}
		 	else {
				sP.rotationY += 5;
		 	}
	  	}
		else if(event.keyCode == Keyboard.LEFT) {
			if(event.shiftKey == false) { 	
				sP.x -=10;
		 	}
		 	else {
				sP.rotationY -= 5;
		 	}
	  	}
	  
	  }
	}
}

AS3-koodin oleelliset kohdat:

1) Flash Professional CS4:lla Flash-komponentteja tehdessä voi upottaa Action Script -koodin suoraan pääaikajanan tai objektien omien aikajanojen frameihin. Usein pienissä sovelluksissa onkin kätevää koodata kaikki Action Script -koodi pääaikajanan frameen 1.

Vähänkään isommissa ohjelmointiprojekteissa on kuitenkin suositeltavampaa käyttää AS3:n olio-ohjelmointiominaisuuksia hyödyksi ja kirjoittaa AS3-koodi yhden tai useamman luokan sisään.

AS3-luokiksi pakattua koodia voi käyttää sovelluksissaan joko

a) luomalla aikajanalla olevassa koodissaan luokan ilmentymiä / käyttämällä luokan staattisia muuttujia tai metodeja. Tällöin täytyy muistaa ottaa tarvittavat luokat käyttöön import-lauseiden avulla.

b) Tekemällä jostain AS3-luokasta pääluokan, joka käynnistetään sovelluksen käynnistyessä. Käytän tässä tutoriaalissani b-kohdan tapaa, joka onnistuu tässä tapauksessa FP CS4:lla:

2) AS3-luokkia käyttäessään on hyvä tietää:

          	
1) AS3-luokat kirjoitetaan pakkausten (package) sisään.
2) Luokat voi kirjoittaa suoraan sovelluksensa päähäkemistoon nimettömään pakkaukseen
   luokkan nimiseen as-tiedostoon. 
	
    Esim.
	luokka: Away3DSphere,
	lähdekooditiedosto: Away3DSphere.as
	lähdekoositiedoston perusmuoto:
        
    package {
        import away3d.cameras.HoverCamera3D;
        
        public class Away3DSphere extends Sprite {
            private var scene:Scene3D;
 
            public function Away3DSphere()
            {
                scene             = new Scene3D();
            }
        }
    }
        
3) Pakkauksia voi (ja usein näin myös tehdään) tallentaa päähakemiston alaisiin
   alihakemistoihin. 
   
   Esim. 
   Yllä olevassa tapauksessa voisimme tallentaa luokan Away3DSphere
   alihakemistoon geom.
   Tällöin täytyy muistaa:
   a) Muuttaa ensimmäinen rivi
   	package geom {
   b) Luokkaa AS3-koodissa käytettäessä pitää antaa paketin ja luokan nimi:
	import geom.Away3DSphere;

4) Voi siis aina saada kaikki lähdekoodipakkaukset käyttöösi kopioimalla niiden
   hakemistot (alihakemistoineen) projektisi päähakemistoon (säilyttäen
   alkuperäisen hakemistorakenteen).

5) Kuitenkin, jos käytät jotain lähdekoodipakkauksia usein lienee kätevintä
   lisätä kyseisen pakettihakemiston juurihakemisto AS3-kääntäjän asetuksiin:
   
   Edit -> Preferences...
   Category: ActionScript
   Language: Action Script 3.0 Settings...
   Lisää kyseinen juurihakemisto source path -kenttään.

3) Käyttöliittymän nappeja (toimintoineen) on helppo lisätä joko CS4:n graafisen käyttöliittymän kautta suoraan aikajanalle tai sitten kuten tässä teen lisäämällä napit ja tapahtumankäsittelijät AS3-koodilla:

            
1) import-lause alkuun:

	import fl.controls.Button;            

2) Nappeja vastaavien yksityisten (private) muuttujien esittelyt luokan alkuun:

    private var earthDayBtn:Button;
    private var earthNightBtn:Button;
    private var mapBtn:Button;
    
    private var loadBtn:Button;
    private var savePNGBtn:Button;
    private var saveJPGBtn:Button;
    
3) Alustetaan napit ja kytketään tapahtumankäsittelijät konstruktorifunktiossa:

    var tF:TextFormat = new TextFormat();
    tF.color          = 0x000000;
    tF.font           = "Verdana";
    tF.size           = 10;
    
    earthDayBtn = new Button();
    earthDayBtn.setStyle("textFormat", tF);
    earthDayBtn.label = "Maa (päivä)";
    
    earthDayBtn.addEventListener(MouseEvent.CLICK, earthDayBtnHandler);
    stage.addChild(earthDayBtn);
    
    earthDayBtn.x = 25;
    earthDayBtn.y = 20;
    
    earthNightBtn = new Button();
    earthNightBtn.setStyle("textFormat", tF);
    earthNightBtn.label = "Maa (yö)";
    
    earthNightBtn.addEventListener(MouseEvent.CLICK, earthNightBtnHandler);
    stage.addChild(earthNightBtn);
    
    earthNightBtn.x = 155;
    earthNightBtn.y = 20;
    
    mapBtn = new Button();
    mapBtn.setStyle("textFormat", tF);
    mapBtn.label = "Karttoja";
    
    mapBtn.addEventListener(MouseEvent.CLICK, mapBtnHandler);
    stage.addChild(mapBtn);
    
    mapBtn.x = 285;
    mapBtn.y = 20;
    
    loadBtn = new Button();
    loadBtn.setStyle("textFormat", tF);
    loadBtn.label = "Lataa kuva";
    
    loadBtn.addEventListener(MouseEvent.CLICK, loadBtnHandler);
    stage.addChild(loadBtn);
    
    loadBtn.x = 415;
    loadBtn.y = 20;
    
    savePNGBtn = new Button();
    savePNGBtn.setStyle("textFormat", tF);
    savePNGBtn.label = "Tallenna PNG";
    
    savePNGBtn.addEventListener(MouseEvent.CLICK, savePNGBtnHandler);
    stage.addChild(savePNGBtn);
    
    savePNGBtn.x = 545;
    savePNGBtn.y = 20;
    
    saveJPGBtn = new Button();
    saveJPGBtn.setStyle("textFormat", tF);
    saveJPGBtn.label = "Tallenna JPG";
    
    saveJPGBtn.addEventListener(MouseEvent.CLICK, saveJPGBtnHandler);
    stage.addChild(saveJPGBtn);
    
    saveJPGBtn.x = 675;
    saveJPGBtn.y = 20;
    
4) Toteutetaan nappeihin kytketyt tapahtumankäsittelijäfunktiot luokan Away3DSphere
   jäsenfunktioina.
   
   Esim. 
   mapBtn-napin tapahtumankäsittelijäfunktio mapBtnHandler:


    function mapBtnHandler(e:MouseEvent):void
    {
        var linkURL:URLRequest = new URLRequest("http://planetpixelemporium.com/earth.html"); 
        navigateToURL(linkURL); 
    }

4) Hiirikäyttöisen näkymän objektien ja kameran liikuttelun toteuttaminen on tehty Away3D:ssa varsin helpoksi. Etenkin HoverCamera3D-luokan käyttö mahdollistaa varsin näyttävien käyttöliittymien toteuttamisen melko pienellä vaivalla.

            
1) Kameran ja muiden tarvittavien jäsenmuuttujien lisääminen 
   luokkaan Away3DSphere.
 	
    private var camera:HoverCamera3D;
    private var scene:Scene3D;
    private var view:View3D;
    
    private var move:Boolean = false;
    private var lastPanAngle:Number;
    private var lastTiltAngle:Number;
    private var lastMouseX:Number;
    private var lastMouseY:Number;
    
2) Kameran ja muiden jäsenmuuttujien alustaminen luokan konstruktorissa. 

    scene             = new Scene3D();
    
    camera = new HoverCamera3D();
    camera.x            = 0;
    camera.y            = 0;
    camera.z            = -200;
    
    camera.mintiltangle = 15;
    camera.maxtiltangle = 65;
    
	view = new View3D({width:800, height:600, x:400, y:300, camera:camera, scene:scene});    

3) Tapahtumankäsittelijöiden kytkeminen hiiren toimintaan.

    addEventListener(Event.ENTER_FRAME, enterFrameHandler);
    stage.addEventListener(MouseEvent.MOUSE_DOWN, MouseDown);
    stage.addEventListener(MouseEvent.MOUSE_UP, MouseUp);

4) Tapahtumankäsittelijöiden toteutus.

function MouseDown(e:MouseEvent):void
{
    lastPanAngle = camera.targetpanangle;
    lastTiltAngle = camera.targettiltangle;
    lastMouseX = stage.mouseX;
    lastMouseY = stage.mouseY;
    move = true;
}
 
function MouseUp(e:MouseEvent):void
{
    move = false;
}
 
function enterFrameHandler(e:Event):void
{
    // rerender viewport
    var cameraSpeed:Number = 0.3; // Approximately same speed as mouse movement.
    if (move) {
        camera.targetpanangle = cameraSpeed*(stage.mouseX - lastMouseX) + lastPanAngle;
        camera.targettiltangle = cameraSpeed*(stage.mouseY - lastMouseY) + lastTiltAngle;
    }
    
    camera.hover(); 
    view.render();
}

5) Näppäinkomentojen lisääminen:


1) Kytketään luokan konstruktorissa näppäintenkuuntelija funktio keyPressed.

	stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);            

2) Lisätään luokkaan Away3DSphere tapahtumankäsittelijäksi jäsenfunktio keyPressed.

    // The KeyboardEvent.KEY_DOWN event handler manage key pressed by user
    private function keyPressed(event:KeyboardEvent):void
    {
         if(event.keyCode == Keyboard.UP) {
            if(event.shiftKey == false) { 
                sP.y +=10;
            }
            else {
                sP.rotationX += 5;
            }
            
            if(event.ctrlKey == true) { 	
                camera.distance -= 20;
            }
         }
         else if(event.keyCode == Keyboard.DOWN) {
            if(event.shiftKey == false) { 
                sP.y -=10;
            }
            else {
                sP.rotationX -= 5;
            }
            
            if(event.ctrlKey == true) { 	
                camera.distance += 20;
            }
         }
         else if(event.keyCode == Keyboard.RIGHT) {
            if(event.shiftKey == false) { 	
                sP.x +=10;
            }
            else {
                sP.rotationY += 5;
            }
        }
        else if(event.keyCode == Keyboard.LEFT) {
            if(event.shiftKey == false) { 	
                sP.x -=10;
            }
            else {
                sP.rotationY -= 5;
            }
        }   
    }

6) Kuvan lataaminen Flash-komponenttiin FileReference-luokan avulla.

          	
1) Lisätään FileReference- ja Loader-luokkien ilmentymät luokan Away3DSphere 
   yksityisiksi jäsenmuuttujaksi:

	private var loadFileRef:FileReference = new FileReference();
 	private var loader:Loader;
    
2) Lisätään luokkaan lataustapahtuman käynnistävä nappi:

	private var loadBtn:Button;	    

3) Lisätään tapahtumankäsittelijät FileReference-objektiin luokan konstruktorissa:

	loadFileRef.addEventListener(Event.SELECT, fileSelected);
	loadFileRef.addEventListener(Event.COMPLETE, loadCompleted);
	loadFileRef.addEventListener(IOErrorEvent.IO_ERROR, ioerror);                
 
4) Alustetaan luokan konstruktorissa latausnappin ilmentymä:

	loadBtn = new Button();
	loadBtn.setStyle("textFormat", tF);
	loadBtn.label = "Lataa kuva";
			
	loadBtn.addEventListener(MouseEvent.CLICK, loadBtnHandler);
	stage.addChild(loadBtn);            
    
5) Toteutetaan kaikki yllä mainitut tapahtumankäsittelijät luokan jäsenfunktioina:

    function loadBtnHandler(e:MouseEvent):void
    {
        loadFileRef.browse();
    } 
    
    // called after a file has been selected within the file system browser
    private function fileSelected(evt:Event):void {
        loadFileRef.load();
    }
    
    // load has completed
    private function loadCompleted(e:Event):void {
        loader = new Loader();
    
        loader.contentLoaderInfo.addEventListener(Event.COMPLETE,imageLoadComplete);
        loader.loadBytes(loadFileRef.data);
    }
    
    // This will execute when load completes
    private function imageLoadComplete(e:Event):void {
        var bt:Bitmap = loader.content as Bitmap;
        image = bt.bitmapData;
        sP.material = new PhongBitmapMaterial(image, {shininess:30,specular:0.8});
    }
    
    // load error
    public function ioerror(e:IOErrorEvent):void{
        //Alert.show(e.text,"Error");
    }

7) Flash-komponentin sisällön tallentaminen JPG- tai PNG-kuvaksi.

Itse opettelin aikoinaan JPG-kuvien kaappaamisen Flash-komponentista tämän tutoriaalin avulla. Kuvan kaappaustoiminnon toteuttaminen edellyttää siis as3corelibin asentamista koneelle. Tämän voi asentaa vaikkapa vain purkamalla kyseisen paketin projektihakemistoon oikean hakemistohierarkian säilyttäen.

Kun as3corelib on oikein asennettu, voimme tehdä tarvittavat lisäykset AS3-koodiin:

          	
1) Lisätään import-lauseet tiedoston Away3DSphere.as alkuosaan:

	import com.adobe.images.PNGEncoder;
    import com.adobe.images.JPGEncoder;

2) Lisätään JPGEncoder-luokan jäsenmuuttuja luokkaan.
   Luokaa PNGEncoder voimme käyttää staattisten funktioiden kautta, joten
   sen ilmentymää emme tarvitse.

	private var jpg:JPGEncoder = new JPGEncoder(100);

3) Lisätään tallennusnapit luokan jäsenmuuttujiksi:

    private var savePNGBtn:Button;
    private var saveJPGBtn:Button;
    
4) Lisätään latausdialogin toteuttava FileReference-muuttuja luokkaan:

	private var saveFileRef:FileReference = new FileReference();    
    
5) Alustetaan tallennusnapit luokan konstruktorissa:

    var tF:TextFormat = new TextFormat();
    tF.color          = 0x000000;
    tF.font           = "Verdana";
    tF.size           = 10;

	savePNGBtn = new Button();
    savePNGBtn.setStyle("textFormat", tF);
    savePNGBtn.label = "Tallenna PNG";
    
    savePNGBtn.addEventListener(MouseEvent.CLICK, savePNGBtnHandler);
    stage.addChild(savePNGBtn);
    
    savePNGBtn.x = 545;
    savePNGBtn.y = 20;
    
    saveJPGBtn = new Button();
    saveJPGBtn.setStyle("textFormat", tF);
    saveJPGBtn.label = "Tallenna JPG";
    
    saveJPGBtn.addEventListener(MouseEvent.CLICK, saveJPGBtnHandler);
    stage.addChild(saveJPGBtn);
    
    saveJPGBtn.x = 675;
    saveJPGBtn.y = 20;

6) Lisätään nappien tapahtumankäsittelijäfunktiot luokkaan jäsenfunktioina.
   Samalla lisäämme kuvankaappauksen suorittavat apufunktiot.

    function savePNGBtnHandler(e:MouseEvent):void
    {
        capturePNG();
    }
    
    // capture image and save back to client
    private function capturePNG():void{
        var bitmapData:BitmapData = new BitmapData(this.width, this.height);
        bitmapData.draw(this);
        var ba:ByteArray = PNGEncoder.encode(bitmapData);
        
        saveFileRef.save(ba,"image.png");
    }
    
    function saveJPGBtnHandler(e:MouseEvent):void
    {
        captureJPG();
    }
    
    // capture image and save back to client
    private function captureJPG():void{
        var bitmapData:BitmapData = new BitmapData(this.width, this.height);
        bitmapData.draw(this);
        var ba:ByteArray = jpg.encode(bitmapData);
        
        saveFileRef.save(ba,"image.jpg");
    }

Loppukommentit

Toivottavasti tässä tutoriaalissani tekemäni planeettaselain innostaa joitain teistä tekemään omia pidemmälle kehitettyjä nettisovelluksia Away3D-kirjaston avulla.

Tässäkin tutoriaalissani olen jälleen kerran osoittanut:

Flashillä pystyy nykyisin tekemään melkein millaisen tahansa sovelluksen joka pyörii käyttäjän nettiselaimessa (ja Flash Playerissä, molemmat saatavissa useimpiin ympäristöihin).

Jos äskeiseen vielä lisätään Flashin kyky kommunikoida palvelinpuolen skriptien ja ohjelmien kanssa, ei taivaskaan enää ole rajana sovelluksia kehiteltäessä...

Takaisin Flash-ohjelmoinnin etusivulle

Flash Away3D: Planeettaselain omilla kuvilla